Normalization

Some effect could accept values in the -1,1 range, some other in the -2,2 range, while some other in the 0,1000 range.
To avoid having to deal with these ranges, you can specify to use a normalized value in the range of 0.00,1.00, where 0.00 is the minimum (0%) and 1.00 is the maximum (100%)

class SomeEffect : SPPEffect {
	override void onInit() {
		normalized(true);
		setOverlayFactor(0.50); // 50%
	}
}
							

By default, normalization is set to false for backward compatibility reasons.
I highly recommend using normalization.
If you're interested in the actual value ranges, you can find them in game scripts.

Priority and Operator

You may be wondering what would happen when two different PPEffects are active at the same time, and they both set the same effect parameter (e.g. vignette intensity, chromatic aberration, radial blur etc.) to different values.

Each parameter you set in your PPEffect can be seen as a layer (like on Photoshop).
These "layers" (parameters) are put on top of each other, and they will interact with the underlying (active) layer.
Which PPEffect takes precendence and how it interacts with other PPEffects is up to you to define via two parameters:

• Priority: defines the order of the layer.

  Higher priority, means it will be on top of those with lower priority

• Operator: defines the way it will interact with the underlying layer

The "first layer", the one at the bottom of the stack, is the default one defined by DayZ itself.

Let's see a practical example with code

For the tutorial sake, I chose low priorities; it's advised to choose higher priorities value (e.g. 100, 200, 500) so that it will be easier to interoperate with other mods.

• Let's pretend the player got hurt; we activate a PainEffect
  The PainEffect will ADD 0.70 to the current vignette intensity.

  
  class PainEffect : SPPEffect {
  	override void onInit() {
  		normalized(true);
  		priority(1);
  		op(PPOperators.ADD);
  		setVignetteIntensity(0.70);
  	}
  }
  									

  	Priority	Operator	Value
  final result			0.70
  PainEffect	1	ADD	0.70
  default	0	SET	0

• Now the player assumed a pain killer and we activate a PainKillerEffect.
  The PainKillerEffect will SUBTRACT0.30 from the vignette intensity.

  
  class PainKillerEffect : SPPEffect {
  	override void onInit() {
  		normalized(true);
  		priority(2);
  		op(PPOperators.SUBSTRACT);
  		setVignetteIntensity(0.30);
  	}
  }
  									

  	Priority	Operator	Value
  final result			0.40
  PainKillerEffect	2	SUBTRACT	0.30
  PainEffect	1	ADD	0.70
  default	0	SET	0

• Now the player got inside a bunker and it's dark; we activate a DarknessEffect.
  The DarknessEffect will MULTIPLY by 2.0
  

  
  class DarknessEffect : SPPEffect {
  	override void onInit() {
  		normalized(true);
  		priority(3);
  		op(PPOperators.MULTIPLICATION);
  		setVignetteIntensity(2);
  	}
  }
  									

  	Priority	Operator	Value
  final result			0.80
  DarknessEffect	3	MULTIPLICATIVE	2
  PainKillerEffect	2	SUBTRACT	0.30
  PainEffect	1	ADD	0.70
  default	0	SET	0

• Now pain killer effectiveness has vanished (but the player is still in pain and in the bunker).
  So we deactivate the PainKillerEffect

  	Priority	Operator	Value
  final result			1.40
  DarknessEffect	3	MULTIPLICATIVE	2
  PainEffect	1	ADD	0.70
  default	0	SET	0

• The player is no longer in pain.
  We deactivate the PainEffect

  	Priority	Operator	Value
  final result			0.00
  DarknessEffect	3	MULTIPLICATIVE	2
  default	0	SET	0

  Currently the DarknessEffect is not affecting the vignette intensity at all; that's because of its operator (2 * 0 = 0).
  As you can see, the priority and the operator play a major role in definining how the final resul will be.
  Be mindful when choosing them, as they could affect other mods too.

For backward compatibility reasons, the default priority is 1000 and the default operator is SET if they're not specified.
If you're upgrading your mod, it's highly recommended to choose the appropriate priority and operator for your PPEffects.

Multiple parameters in the same PPEffect

A PPEffect can "request" multiple parameters at the same time.

You're free to set a different priority and a different operator for each parameter, since each parameter will "affect its own stack of layers".
Altough most of the time it's recommended to use the same for the sake of simplicity.

class Effect_A : SPPEffect {
	override void onInit() {
		normalized(true);
		
		priority(1);
		op(PPOperators.ADD);
		setVignetteIntensity(0.50);
		
		priority(420);
		op(PPOperators.MULTIPLICATIVE);
		setOverlayFactor(2.0);

	}
}

class Effect_B : SPPEffect {
	override void onInit() {
		normalized(true);
		
		priority(69);
		op(PPOperators.SUBTRACT);
		setVignetteIntensity(0.20);
		
		priority(1);
		op(PPOperators.ADD);
		setOverlayFactor(0.40);

	}
}
							

Effects intensity option

Some players may enjoy more intense effects for immersion, while some other may find them too distracting.
With sVisual, the players can change an option to specify their preferred "effects intensity".

You can get the player preference by invoking the getEffectsIntensity() method, which will return a value between 0 and 2 (inclusive)

How this value will affect your effects it's up to you; you may want a specific effect to scale differently based on the player preference.

As a rule of thumb:

• An effect intensity value of 0, means that the player want the least possible effects on the screen
• Effect intensity of 1 is the default
• An effect intensity of 2, means the player like very strong effects

This method is only available if you're using sVisual; so make sure to have specified sVisual in the requiredAddons

Let's see an example

class PainEffect : SPPEffect {
	override void onInit() {
		normalized(true);
		priority(1);
		op(PPOperators.ADD);
		setVignetteIntensity(0.20 * getEffectsIntensity());
	}
}